Perl 社區并不是所有的東西都發布在 CPAN 上。甚至專門有一個 Module::ThirdParty 模塊記錄這些非 CPAN 的 perl 項目列表。其中最有名的應該就屬寫博客的 Movable Type 和做監控的 SmokePing 了。
但是如果個人圖方便又想把 smokeping 打包方便部署使用的時候，就會發現一點小問題：打包成rpm，很多 perl 的依賴模塊不一定在系統 repo 里存在；打包成 perl 的模塊，smokeping 最常用的幾個 probe 比如 fping、curl 什么的，又是非 perl 程序，cpanm 沒法解決這個 requires_external_bin ，最多只能報錯退出。
其實這里可以采取一些別的辦法，雖然笨一些，但是解決問題。
首先還是讓我們創建一個示例模塊：
復制代碼 代碼如下:
cpanm Module::Starter Module::Build
module-starter --module Alien::FPing --author="Jeff Rao" --email="myname@gmail.com" --mb
然后就會在本目錄下創建一個 Alien-FPing 目錄，自帶好了 Build.PL 等模塊文件。這里使用了 Alien:: 的名字空間，是一個潛規則，有些項目依賴 C 源碼的庫和頭文件，就用 perl 包一層來安裝，都放在這個空間下，比如 Alien::V8, Alien::Gearmand, Alien::IE7 等等。
現在讓我們下載 fping 的源碼放到模塊里：
復制代碼 代碼如下:
mkdir Alien-FPing/src
wget http://www.fping.org/dist/fping-3.4.tar.gz -O Alien-FPing/src/fping-3.4.tar.gz
接下來應該就是編寫 Build.PL 了。不過為了盡量讓 Build.PL 看起來簡潔而且一眼看出目的。我們最好把編譯操作單獨定義一個模塊來使用：
復制代碼 代碼如下:
package Alien::FPing::Build;
use base qw(Module::Build);
use File::Spec;
use Archive::Tar;
my $RootDir = File::Spec->rel2abs(".");
my $SrcDir = File::Spec->catdir($RootDir, "src");
my $FPingVersion = '3.4';
my $FPingName = "fping-${FPingVersion}";
my $FPingSrc = "${FPingName}.tar.gz";
sub ACTION_build {
my $self = shift;
chdir($SrcDir);
if ( !-x "/usr/sbin/fping" and !-d $FPingName ) {
my $tar = Archive::Tar->new();
$tar->read($FPingSrc);
$tar->extract();
chdir($FPingName);
system('./configure', '--prefix=/usr/', '--enable-ipv6');
system('make');
system('make install');
}
$self->SUPER::ACTION_build();
};
1;
幾乎就是調用 shell 而已，唯一需要講一下的就是這個 ACTION_build。這是 Module::Build 定義好的提供給 subclass 用的方法，事實上 ./Build help 看得到的所有 action 都有類似的方法可以用。
然后稍微修改一下 Build.PL 如下：
復制代碼 代碼如下:
use 5.006;
use strict;
use warnings FATAL => 'all';
use lib 'inc';
use Alien::FPing::Build;
my $builder = Alien::FPing::Build->new(
module_name => 'Alien::FPing',
license => 'perl',
dist_author => q{Jeff Rao myname@gmail.com>},
dist_version_from => 'lib/Alien/FPing.pm',
release_status => 'stable',
configure_requires => {
'Module::Build' => 0,
},
build_requires => {
'Test::More' => 0,
},
requires => {
#'ABC' => 1.6,
#'Foo::Bar::Module' => 5.0401,
},
add_to_cleanup => [ 'Alien-FPing-*' ],
create_makefile_pl => 'traditional',
);
$builder->create_build_script();
把 Module::Build 替換成 Alien::FPing::Build 而已，其他都不用動。
然后試一下吧：
復制代碼 代碼如下:
cd Alien-FPing
perl Build.PL
./Build
看到編譯輸出，并且成功安裝有 /usr/sbin/fping 了吧。現在可以打包了。注意默認生成的 ignore.txt 里，是排除掉了 inc 目錄的，需要去除掉，然后修改 MANIFEST 文件加入 inc 和 src 里的文件，然后再打包出來的 perl 模塊就可以直接用了。
復制代碼 代碼如下:
sed -i '/inc/d' ignore.txt
echo 'inc/Alien/FPing/Build.pm' >> MANIFEST
echo 'src/fping-3.4.tar.gz' >> MANIFEST
./Build dist
